Hướng dẫn sử dụng hàm IF trong Excel | Excel IF Function

Trong bài viết này 1Kynang sẽ chia sẻ với các bạn kiến thức cô đọng nhất để giúp các bạn hiểu nhanh, đúng có thể sử dụng hiệu quả hàm IF trong Excel vào công việc

I. Hàm IF trong Excel và cách sử dụng  

Hàm IF trong Excel sử dụng để kiểm tra một điều kiện cụ thể và trả về một giá trị cho kết quả TRUE và một giá trị khác cho kết quả FALSE.

Ví dụ:

Điều kiện để Sinh viên Đạt thì điểm thi trên 70 điểm; =IF(C5>70,"Đạt","Không đạt").

Nhiều hơn một điều kiện có thể được kiểm tra bằng cách lồng các hàm IF. Hàm IF có thể được kết hợp với các hàm logic như AND và OR để mở rộng kiểm tra logic

1. Hàm If sử dụng để làm gì

Kiểm tra một điều kiện cụ thể

2. Kết quả trả về hàm IF

Giá trị bạn cung cấp khi điều kiện kiểm tra là TRUE hay FALSE

3. Cấu trúc hàm IF

= IF (logic_test, [value_if_true], [value_if_false])

4. Giải thích cấu trúc hàm IF

• logic_test: Một giá trị hoặc biểu thức logic có thể được đánh giá là TRUE hoặc FALSE.
• value_if_true: [tùy chọn] Giá trị trả về khi logic_test đánh giá là TRUE.
• value_if_false: [tùy chọn] Giá trị trả về khi logic_test đánh giá là FALSE.

5. Lưu ý khi sử dụng hàm IF

Hàm IF kiểm tra giá trị hoặc biểu thức logic_test và trả về một kết quả nếu giá trị hoặc biểu thức kiểm tra cho kết quả TRUE và trả về một giá trị khác nếu giá trị hoặc biểu thức kiểm tra cho kết quả FALSE

• Đối số đầu tiên logic_test: là một biểu thức trả về kết quả Đúng hoặc Sai
• Đối số thứ hai value_if_true là giá trị trả về khi biểu thức logic_test là Đúng (TRUE)
• Đối số thứ ba value_if_false là giá trị trả về khi biểu thức logic_test là Sai (FALSE)
• Hai đối số cuối của hàm IF, value_if_true và value_if_false đều là đối số tùy chọn (có hoặc không) nhưng ít nhất một trong số chúng phải được cung cấp
• Kết quả hàm IF có thể là một giá trị, một tham chiếu hoặc có thể là một công thức

II. Ví dụ về hàm IF trong Excel  

1. Ví dụ về hàm IF - Đạt hoặc Không đạt   

Ở ví dụ trên, trong cột D, muốn hiển thị Kết quả Đạt hoặc Không đạt dựa trên Điểm của các sinh viên ở cột C. Nếu sinh viên có điểm lớn hơn 70 điểm thì Đạt, còn lại thấp hơn 70 điểm thì Không đạt

Vậy, tại ô D5 chúng ta viết công thức:

💡 =IF(C5>70,"Đạt","Không đạt")

Giải thích công thức: Nếu giá trị trong ô C5 lớn hơn 70 thì điền kết quả Đạt vào ô D5. Còn lại, nhỏ hơn hoặc bằng 70 thì điền Không đạt

Sau đó, bạn kéo áp dụng côgn thức tại ô D5 xuống dưới cho các ô còn lại - Kết quả trả về đúng yêu cầu

2. Ví dụ về hàm IF - Phân chia đội dựa trên giá trị văn bản   

Bạn muốn phân chia đội số 1 hay đội số 2 dựa trên Môn thi đăng ký là Toán hay Văn.

Nếu:

• Môn đăng ký là môn Toán thì thuộc Đội số 1
• Môn đăng ký là môn Văn thì thuộc Đội số 2

Bạn có thể sử dụng công thức sau:

💡 =IF(C5="Toán",1,IF(C5="Văn",2))

Có ba điểm lưu ý khi bạn xử lý tình huống này với hàm IF

• Lưu ý 1: Công thức sẽ trả về kết quả FALSE nếu giá trị trong cột C không phải là Văn hoặc Toán
• Lưu ý 2: Giá trị văn bản kiểm tra trong công thức IF phải được đặt trong dấu “” (Ví dụ “Toán” hoặc “Văn”
• Lưu ý 3: Hàm IF không phân biệt chữ HOA hay chữ thường nên nếu bạn điền TOÁN hoặc toán hoặc Toán thì hàm IF vẫn kiểm tra và trả về kết quả là số 1

3. Ví dụ về hàm IF - Kết quả trả về là một công thức   

Ở các ví dụ trên, bạn đã biết hàm IF trả về một giá trị hay một tham chiếu rồi, thì ở ví dụ này tôi sẽ minh họa rằng, hàm IF - kết quả trả về có thể là một công thức

Tình huống đặt ra là, nếu một nhân viên Sale đạt doanh thu lớn hơn hoặc bằng 300 triệu thì thưởng cho bạn đó 2% doanh thu, còn lại các bạn Sale có doanh thu nhỏ hơn 300 triệu thì không thưởng gì

Công thức xử lý tình huống trên:

💡 =IF(C5>=300000000,C5*2%,0)

• Giá trị trả về có thể linh động là một giá trị, văn bản, tham chiếu ô hay một công thức bất kỳ - Miễn sao, nó phù hợp với mong muốn xử lý của bạn

III. Hàm IF lồng nhau  

Lồng ghép nhiều hàm IF - IF lồng nhau là một công thức trong đó ít nhất một hàm IF được lồng bên trong hàm IF khác để kiểm tra nhiều điều kiện và trả về nhiều kết quả hơn.

Mỗi câu lệnh IF lồng nhau cần được xử lý cẩn thận vào bên trong một câu lệnh khác để thỏa mãn tính Logic của cấu trúc hàm

Ví dụ: Tình huống dưới sử dụng nhiều công thức IF lồng nhau để kiểm tra điểm số sinh viên và trả về kết quả mức xét danh hiệu của sinh viên đó là Giỏi, Khá, Trung bình khá, Trung bình hay Yếu

Công thức xử lý:

💡 =IF(C5<60,"Yếu",IF(C5<70,"Trung bình",IF(C5<80,"Trung bình khá",IF(C5<90,"Khá","Giỏi"))))

Chúng ta có thể lồng ghép 64 hàm IF vào với nhau. Tuy nhiên, bạn có thể xem xét sử dụng linh hoạt các hàm khác như VLOOKUP, HLOOKUP cho các tình huống phức tạp hơn để việc xử lý hàm của chúng ta trở lên đơn giản, tinh gọn hơn

Lưu ý: Bạn có thể sử dụng hàm IFS xử lý nhiều điều kiện mà không cần lồng ghép nhiều hàm IF lại với nhau

IV. Hàm IF kết hợp với hàm AND, OR trong Excel  

1. Hàm IF kết hợp với hàm AND trong Excel   

Nếu bạn muốn kiểm tra nhiều giá trị hay biểu thức thỏa mãn đồng thời

• Nếu chúng cùng thỏa mãn, từng biểu thức kiểm tra Đúng thì trả về một giá trị
• Nếu một trong các điều kiện không thỏa mãn, tức biểu thức kiểm tra Sai thì trả về kết quả khác

Ở ví dụ trên, tình huống đặt ra là Kiểm tra Doanh thu bán hàng và Số lượng khách hàng để lại Đánh giá Tốt cho sản phẩm

• Nếu doanh thu > 300 triệu và Số lượng đánh giá Tốt > 200 đánh giá thì Sản phẩm được đánh giá là Tốt
• Còn lại thì Sản phẩm có Nhận xét Xem lại để cải thiện

Công thức xử lý tình huống trên:

💡 =IF(AND(C5>300000000,D5>200),"Tốt","Xem lại")

2. Hàm IF kết hợp với hàm OR trong Excel

Vẫn với tình huống trên, chúng ta đánh giá sản phẩm Tốt khi sản phẩm thỏa mãn một trong hai tiêu chí

• Doanh thu > 300 triệu

Or

• Số lượn Đánh giá Tốt của sản phẩm > 200 đánh giá

Khi một sản phẩm nào đó, thỏa mãn một trong hai tiêu chí kiểm tra ở trên thì chúng ta điền Nhận xét Tốt cho sản phẩm tương ứng

Công thức xử lý:

💡 =IF(OR(C5>300000000,D5>200),"Tốt","Xem lại")

V. Ghi chú và kiến thức xoay quanh hàm IF  

• Hàm IF không phân biệt chữ hoa và chữ thường
• Để đếm các giá trị có điều kiện thì hãy sử dụng hàm COUNTIF hoặc COUNTIFS
• Để tính tổng các giá trị có điều kiện thì hãy sử dụng hàm SUMIF hoặc SUMIFS
• Nếu bất kỳ đối số nào của hàm IF được cung cấp dưới dạng mảng thì hàm IF sẽ đánh giá mọi phần thử của mảng